blob: b15ad323eb80fffa10fbce82e93aad3d50d26ec1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
;;; guile-2d
;;; Copyright (C) 2013 David Thompson <dthompson2@worcester.edu>
;;;
;;; Guile-2d is free software: you can redistribute it and/or modify it
;;; under the terms of the GNU Lesser General Public License as
;;; published by the Free Software Foundation, either version 3 of the
;;; License, or (at your option) any later version.
;;;
;;; Guile-2d is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
;;; Lesser General Public License for more details.
;;;
;;; You should have received a copy of the GNU Lesser General Public
;;; License along with this program. If not, see
;;; <http://www.gnu.org/licenses/>.
;;; Commentary:
;;
;; 2D sprite procedures.
;;
;;; Code:
(define-module (2d sprite)
#:use-module (srfi srfi-9)
#:use-module (figl gl)
#:use-module (2d texture)
#:use-module (2d vector)
#:export (make-sprite
sprite?
sprite-texture
sprite-position
set-sprite-position!
sprite-scale
set-sprite-scale!
sprite-rotation
set-sprite-rotation!
set-sprite-scale!
load-sprite
draw-sprite))
;; The <sprite> object represents a texture with a given position, scale,
;; rotation, and color.
(define-record-type <sprite>
(%make-sprite texture position scale rotation color anchor)
sprite?
(texture sprite-texture)
(position sprite-position set-sprite-position!)
(scale sprite-scale set-sprite-scale!)
(rotation sprite-rotation set-sprite-rotation!)
(color sprite-color set-sprite-color!)
(anchor sprite-anchor set-sprite-anchor))
(define (sprite-anchor-vector sprite)
(let ((anchor (sprite-anchor sprite)))
(cond
((eq? anchor 'center)
(let ((texture (sprite-texture sprite)))
(vector (/ (texture-width texture) 2)
(/ (texture-height texture) 2))))
(else anchor))))
(define* (make-sprite texture #:optional #:key (position #(0 0)) (scale #(1 1))
(rotation 0) (color '(1 1 1)) (anchor 'center))
"Makes a new sprite object."
(%make-sprite texture position scale rotation color anchor))
(define* (load-sprite filename #:optional #:key (position #(0 0)) (scale #(1 1))
(rotation 0) (color '(1 1 1)) (anchor 'center))
"Loads a sprite from file."
(make-sprite (load-texture filename) #:position position #:scale scale
#:rotation rotation #:color color #:anchor anchor))
(define (draw-sprite sprite)
"Renders a sprite."
(let* ((texture (sprite-texture sprite))
(width (texture-width texture))
(height (texture-height texture))
(pos (sprite-position sprite))
(scale (sprite-scale sprite))
(anchor (sprite-anchor-vector sprite)))
(with-gl-push-matrix
(gl-translate (vx pos) (vy pos) 0)
(gl-rotate (sprite-rotation sprite) 0 0 1)
(gl-scale (vx scale) (vy scale) 0)
;; Render a textured quad center on the sprite position.
(texture-quad texture
(- (vx anchor)) (- (vy anchor))
width height
(sprite-color sprite)))))
|
