blob: 46d6c1224058c936c383be4746ab5d60c18c7fa0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
|
;;; guile-2d
;;; Copyright (C) 2013 David Thompson <dthompson2@worcester.edu>
;;;
;;; Guile-2d is free software: you can redistribute it and/or modify it
;;; under the terms of the GNU Lesser General Public License as
;;; published by the Free Software Foundation, either version 3 of the
;;; License, or (at your option) any later version.
;;;
;;; Guile-2d is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
;;; Lesser General Public License for more details.
;;;
;;; You should have received a copy of the GNU Lesser General Public
;;; License along with this program. If not, see
;;; <http://www.gnu.org/licenses/>.
;;; Commentary:
;;
;; Deferred procedure scheduling.
;;
;;; Code:
(define-module (2d agenda)
#:use-module (ice-9 q)
#:use-module (srfi srfi-1)
#:use-module (srfi srfi-9)
#:use-module (srfi srfi-26)
#:use-module (2d coroutine)
#:export (make-agenda
*global-agenda*
current-agenda
with-agenda
schedule
schedule-interval
schedule-next
schedule-every
tick-agenda!
clear-agenda!
wait))
;; This code is a modified version of the agenda implementation in
;; SICP. Thank you, SICP!
;;;
;;; Time segment
;;;
(define-record-type <time-segment>
(%make-time-segment time queue)
time-segment?
(time segment-time)
(queue segment-queue))
(define (make-time-segment time . callbacks)
"Create a new time segment at TIME and enqueues everything in the
list CALLBACKS."
(let ((segment (%make-time-segment time (make-q))))
;; Enqueue all callbacks
(for-each (cut segment-enq segment <>) callbacks)
segment))
(define (segment-enq segment callback)
"Add the CALLBACK procedure to SEGMENT's queue."
(enq! (segment-queue segment) callback))
;;;
;;; Agenda
;;;
(define-record-type <agenda>
(%make-agenda time segments)
agenda?
(time agenda-time set-agenda-time!)
(segments agenda-segments set-agenda-segments!))
(define (make-agenda)
"Create a new, empty agenda."
(%make-agenda 0 '()))
(define (agenda-empty? agenda)
"Return #t if AGENDA has no scheduled procedures."
(null? (agenda-segments agenda)))
(define (first-segment agenda)
"Return the first time segment in AGENDA."
(car (agenda-segments agenda)))
(define (rest-segments agenda)
"Return everything but the first segment in AGENDA."
(cdr (agenda-segments agenda)))
(define (agenda-add-segment agenda time callback)
"Add a new time segment to the beginning of AGENDA at the given TIME
and enqueue CALLBACK."
(set-agenda-segments! agenda
(cons (make-time-segment time callback)
(agenda-segments agenda))))
(define (insert-segment segments time callback)
"Insert a new time segment after the first segment in SEGMENTS."
(set-cdr! segments
(cons (make-time-segment time callback)
(cdr segments))))
(define (first-agenda-item agenda)
"Return the first time segment queue in AGENDA."
(if (agenda-empty? agenda)
(error "Agenda is empty")
(segment-queue (first-segment agenda))))
(define (agenda-time-delay agenda dt)
"Return the sum of the time delta, DT, and the current time of AGENDA."
(+ (agenda-time agenda) (inexact->exact (round dt))))
(define (%agenda-schedule agenda callback dt)
"Schedule the procedure CALLBACK in AGENDA to be run DT updates from now."
(let ((time (agenda-time-delay agenda dt)))
(define (belongs-before? segments)
(or (null? segments)
(< time (segment-time (car segments)))))
(define (add-to-segments segments)
;; Add to existing time segment if the times match
(if (= (segment-time (car segments)) time)
(segment-enq (car segments) callback)
;; Continue searching
(if (belongs-before? (cdr segments))
;; Create new time segment and insert it where it belongs
(insert-segment segments time callback)
;; Continue searching
(add-to-segments (cdr segments)))))
;; Handle the case of inserting a new time segment at the
;; beginning of the segment list.
(if (belongs-before? (agenda-segments agenda))
;; Add segment if it belongs at the beginning of the list...
(agenda-add-segment agenda time callback)
;; ... Otherwise, search for the right place
(add-to-segments (agenda-segments agenda)))))
(define (flush-queue! q)
"Dequeue and execute every member of Q."
(unless (q-empty? q)
((deq! q)) ;; Execute scheduled procedure
(flush-queue! q)))
(define (tick-agenda! agenda)
"Move AGENDA forward in time and run scheduled procedures."
(set-agenda-time! agenda (1+ (agenda-time agenda)))
(let next-segment ()
(unless (agenda-empty? agenda)
(let ((segment (first-segment agenda)))
;; Process time segment if it is scheduled before or at the
;; current agenda time.
(when (>= (agenda-time agenda) (segment-time segment))
(flush-queue! (segment-queue segment))
(set-agenda-segments! agenda (rest-segments agenda))
(next-segment))))))
(define (clear-agenda! agenda)
"Remove all scheduled procedures from AGENDA."
(set-agenda-segments! agenda '()))
;; The global agenda that will be used when schedule is called outside
;; of a with-agenda form.
(define *global-agenda* (make-agenda))
(define current-agenda (make-parameter *global-agenda*))
;; emacs: (put 'with-agenda 'scheme-indent-function 1)
(define-syntax-rule (with-agenda agenda body ...)
(parameterize ((current-agenda agenda))
body ...))
(define (schedule thunk delay)
"Schedule THUNK within the current agenda to be applied after DELAY
ticks."
(%agenda-schedule (current-agenda) thunk delay))
(define* (schedule-interval thunk interval #:optional (delay 1))
"Schedule THUNK within the current agenda to be applied after DELAY
ticks and then to be applied every INTERVAL ticks thereafter. DELAY
is 1 by default."
(%agenda-schedule (current-agenda)
(lambda ()
(thunk)
(schedule-interval thunk interval interval))
delay))
(define (schedule-next thunk)
"Schedule THUNK within the current agenda to be applied upon the
next tick."
(schedule thunk 1))
(define (schedule-every thunk)
"Schedule THUNK within the current agenda to be applied upon every
tick."
(schedule-interval thunk 1))
(define* (wait #:optional (delay 1))
"Yield coroutine and schedule the continuation to be run after DELAY
ticks. DELAY is 1 by default."
(yield (cut schedule <> delay)))
|
