1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
|
(post
:title "Rendering HTML with SXML and GNU Guile"
:date (make-date* 2015 04 10)
:tags '("gnu" "guile" "wsu")
:summary "With a little effort, SXML can be used for HTML templates"
(p [GNU Guile provides modules for working with XML documents called
SXML. SXML provides an elegant way of writing XML documents as
s-expressions that can be easily manipulated in Scheme. Here’s an
example:])
(source-code
(scheme-source
"(sxml->xml '(foo (bar (@ (attr \"something\")))))"))
(source-code
(xml-source
"<foo><bar attr=\"something\" /></foo>"))
(p [I don’t know about you, but I work with HTML documents much more
often than XML. Since HTML is very similar to XML, we should be able
to represent it with SXML, too!])
(source-code
(scheme-source
"(sxml->xml
'(html
(head
(title \"Hello, world!\")
(script (@ (src \"foo.js\"))))
(body
(h1 \"Hello!\"))))"))
(source-code
(xml-source
"<html>
<head>
<title>Hello, world!</title>
<script src=\"foo.js\" /> <!-- what? -->
</head>
<body>
<h1>Hello!</h1>
</body>
</html>"))
(p [That ,(code [<script>]) tag doesn’t look right! Script tags
don’t close themselves like that. Well, we could hack around it:])
(source-code
(scheme-source
"(sxml->xml
'(html
(head
(title \"Hello, world!\")
(script (@ (src \"foo.js\")) \"\"))
(body
(h1 \"Hello!\"))))"))
(source-code
(xml-source
"<html>
<head>
<title>Hello, world!</title>
<script src=\"foo.js\"></script>
</head>
<body>
<h1>Hello!</h1>
</body>
</html>"))
(p [There’s no bug. The improper rendering happens because HTML, while
similar to XML, has some different syntax rules. Instead of using
,(code [sxml->xml]) a new procedure that is tailored to the HTML syntax
is needed. Introducing ,(code [sxml->html]):])
(source-code
(scheme-source
"(define* (sxml->html tree #:optional (port (current-output-port)))
\"Write the serialized HTML form of TREE to PORT.\"
(match tree
(() *unspecified*)
(('doctype type)
(doctype->html type port))
(((? symbol? tag) ('@ attrs ...) body ...)
(element->html tag attrs body port))
(((? symbol? tag) body ...)
(element->html tag '() body port))
((nodes ...)
(for-each (cut sxml->html <> port) nodes))
((? string? text)
(string->escaped-html text port))
;; Render arbitrary Scheme objects, too.
(obj (object->escaped-html obj port))))"))
(p [In addition to being aware of void elements and escape
characters, it can also render ,(code ['(doctype "html")]) as
,(code [<!DOCTYPE html>]). If we replace ,(code [sxml->xml])
with ,(code [sxml->html]) in the failing example above we can see
that it does the right thing.])
(source-code
(scheme-source
"(sxml->html
'((script (@ (src \"foo.js\")))
\"Copyright © 2015 David Thompson <davet@gnu.org>\"))"))
(source-code
(xml-source
"<script src=\"foo.js\"></script>
Copyright © 2015 David Thompson <davet@gnu.org>"))
(p [Here’s the full version of my ,(code "(sxml html)") module. It’s
quite brief, which is a nice bonus. This code requires Guile 2.0.11
or greater.])
(p [Happy hacking!])
(source-code
(scheme-source
";;; Copyright © 2015 David Thompson <davet@gnu.org>
;;;
;;; This library is free software; you can redistribute it and/or
;;; modify it under the terms of the GNU Lesser General Public License
;;; as published by the Free Software Foundation; either version 3 of
;;; the License, or (at your option) any later version.
;;;
;;; This library is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
;;; Lesser General Public License for more details.
;;;
;;; You should have received a copy of the GNU Lesser General Public
;;; License along with this library. If not, see
;;; <http://www.gnu.org/licenses/>.
(define-module (sxml html)
#:use-module (sxml simple)
#:use-module (srfi srfi-26)
#:use-module (ice-9 match)
#:use-module (ice-9 format)
#:use-module (ice-9 hash-table)
#:export (sxml->html))
(define %void-elements
'(area
base
br
col
command
embed
hr
img
input
keygen
link
meta
param
source
track
wbr))
(define (void-element? tag)
\"Return #t if TAG is a void element.\"
(pair? (memq tag %void-elements)))
(define %escape-chars
(alist->hash-table
'((#\\\" . \"quot\")
(#\\& . \"amp\")
(#\\' . \"apos\")
(#\\< . \"lt\")
(#\\> . \"gt\"))))
(define (string->escaped-html s port)
\"Write the HTML escaped form of S to PORT.\"
(define (escape c)
(let ((escaped (hash-ref %escape-chars c)))
(if escaped
(format port \"&~a;\" escaped)
(display c port))))
(string-for-each escape s))
(define (object->escaped-html obj port)
\"Write the HTML escaped form of OBJ to PORT.\"
(string->escaped-html
(call-with-output-string (cut display obj <>))
port))
(define (attribute-value->html value port)
\"Write the HTML escaped form of VALUE to PORT.\"
(if (string? value)
(string->escaped-html value port)
(object->escaped-html value port)))
(define (attribute->html attr value port)
\"Write ATTR and VALUE to PORT.\"
(format port \"~a=\\\"\" attr)
(attribute-value->html value port)
(display #\\\" port))
(define (element->html tag attrs body port)
\"Write the HTML TAG to PORT, where TAG has the attributes in the
list ATTRS and the child nodes in BODY.\"
(format port \"<~a\" tag)
(for-each (match-lambda
((attr value)
(display #\\space port)
(attribute->html attr value port)))
attrs)
(if (and (null? body) (void-element? tag))
(display \" />\" port)
(begin
(display #\\> port)
(for-each (cut sxml->html <> port) body)
(format port \"</~a>\" tag))))
(define (doctype->html doctype port)
(format port \"<!DOCTYPE ~a>\" doctype))
(define* (sxml->html tree #:optional (port (current-output-port)))
\"Write the serialized HTML form of TREE to PORT.\"
(match tree
(() *unspecified*)
(('doctype type)
(doctype->html type port))
(((? symbol? tag) ('@ attrs ...) body ...)
(element->html tag attrs body port))
(((? symbol? tag) body ...)
(element->html tag '() body port))
((nodes ...)
(for-each (cut sxml->html <> port) nodes))
((? string? text)
(string->escaped-html text port))
;; Render arbitrary Scheme objects, too.
(obj (object->escaped-html obj port))))")))
|
