summaryrefslogtreecommitdiff
path: root/starling/kernel.scm
blob: caab692d0a84703b2d6fafc774bb7680efa7944c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
;;; Starling Game Engine
;;; Copyright © 2018 David Thompson <davet@gnu.org>
;;;
;;; This program is free software: you can redistribute it and/or
;;; modify it under the terms of the GNU General Public License as
;;; published by the Free Software Foundation, either version 3 of the
;;; License, or (at your option) any later version.
;;;
;;; This program is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with Starling.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:
;;
;; This is the core of the game engine, the root node, that is
;; responsible for starting up the game loop and passing along render,
;; update, and input events to the other parts of the game.
;;
;;; Code:

(define-module (starling kernel)
  #:use-module (chickadee)
  #:use-module (ice-9 match)
  #:use-module (oop goops)
  #:use-module (sdl2)
  #:use-module (sdl2 events)
  #:use-module (sdl2 input game-controller)
  #:use-module (sdl2 input joystick)
  #:use-module (sdl2 input text)
  #:use-module (sdl2 mixer)
  #:use-module (sdl2 video)
  #:use-module (starling node)
  #:export (on-quit
            on-key-press
            on-key-release
            on-text-input
            on-mouse-press
            on-mouse-release
            on-mouse-move
            on-controller-add
            on-controller-remove
            on-controller-press
            on-controller-release
            on-controller-move
            <window-config>
            width
            height
            title
            fullscreen?
            <kernel>
            window-config
            update-hz
            window
            gl-context
            boot-kernel)
  #:re-export (abort-game))

;; Input event handler methods
(define-method (on-quit (node <node>))
  (abort-game))

(define-method (on-key-press (node <node>) key scancode modifiers repeat?)
  #t)

(define-method (on-key-release (node <node>) key scancode modifiers)
  #t)

(define-method (on-text-input (node <node>) text)
  #t)

(define-method (on-mouse-press (node <node>) button clicks x y)
  #t)

(define-method (on-mouse-release (node <node>) button x y)
  #t)

(define-method (on-mouse-move (node <node>) x y x-rel y-rel buttons)
  #t)

(define-method (on-controller-add (node <node>) controller)
  #t)

(define-method (on-controller-remove (node <node>) controller)
  #t)

(define-method (on-controller-press (node <node>) controller button)
  #t)

(define-method (on-controller-release (node <node>) controller button)
  #t)

(define-method (on-controller-move controller axis value)
  #t)

(define-class <window-config> ()
  (width #:accessor width #:init-form 640)
  (height #:accessor height #:init-form 480)
  (title #:accessor title #:init-form "Made with Starling Game Engine")
  (fullscreen? #:accessor fullscreen? #:init-form #f))

(define-class <kernel> (<node>)
  (name #:accessor name #:init-form "starling-kernel")
  (window-config #:accessor window-config #:init-form (make <window-config>))
  (update-hz #:accessor update-hz #:init-form 60)
  (window #:accessor window)
  (gl-context #:accessor gl-context)
  (controllers #:accessor controllers #:init-thunk make-hash-table))

(define current-kernel (make-parameter #f))

;; game controller bookkeeping.
(define (lookup-controller kernel joystick-id)
  (hashv-ref (controllers kernel) joystick-id))

(define (add-controller kernel joystick-index)
  (let ((controller (open-game-controller joystick-index)))
    (hashv-set! (controllers kernel)
                (joystick-instance-id
                 (game-controller-joystick controller))
                controller)
    controller))

(define (remove-controller kernel joystick-id)
  (hashv-remove! (controllers kernel) joystick-id))

(define (initialize-controllers kernel)
  (let loop ((i 0))
    (when (< i (num-joysticks))
      (when (game-controller-index? i)
        (add-controller kernel i))
      (loop (+ i 1)))))

(define-method (update* (kernel <kernel>) dt)
  (define (invert-y y)
    ;; SDL's origin is the top-left, but our origin is the bottom
    ;; left so we need to invert Y coordinates that SDL gives us.
    (match (window-size (window kernel))
      ((_ height)
       (- height y))))
  (define (process-event event)
    (let ((first-child (car (children kernel))))
      (cond
       ((quit-event? event)
        (on-quit first-child))
       ((keyboard-down-event? event)
        (on-key-press first-child
                      (keyboard-event-key event)
                      (keyboard-event-scancode event)
                      (keyboard-event-modifiers event)
                      (keyboard-event-repeat? event)))
       ((keyboard-up-event? event)
        (on-key-release first-child
                        (keyboard-event-key event)
                        (keyboard-event-scancode event)
                        (keyboard-event-modifiers event)))
       ((text-input-event? event)
        (on-text-input first-child
                       (text-input-event-text event)))
       ((mouse-button-down-event? event)
        (on-mouse-press first-child
                        (mouse-button-event-button event)
                        (mouse-button-event-clicks event)
                        (mouse-button-event-x event)
                        (invert-y (mouse-button-event-y event))))
       ((mouse-button-up-event? event)
        (on-mouse-release first-child
                          (mouse-button-event-button event)
                          (mouse-button-event-x event)
                          (invert-y (mouse-button-event-y event))))
       ((mouse-motion-event? event)
        (on-mouse-move first-child
                       (mouse-motion-event-x event)
                       (invert-y (mouse-motion-event-y event))
                       (mouse-motion-event-x-rel event)
                       (- (mouse-motion-event-y-rel event))
                       (mouse-motion-event-buttons event)))
       ((and (controller-device-event? event)
             (eq? (controller-device-event-action event) 'added))
        (let ((controller
               (add-controller kernel
                               (controller-device-event-which event))))
          (on-controller-add first-child controller)))
       ((and (controller-device-event? event)
             (eq? (controller-device-event-action event) 'removed))
        (let ((controller
               (lookup-controller kernel
                                  (controller-device-event-which event))))
          (on-controller-remove first-child controller)
          (remove-controller kernel (controller-device-event-which event))
          (close-game-controller controller)))
       ((controller-button-down-event? event)
        (let ((controller
               (lookup-controller kernel
                                  (controller-button-event-which event))))
          (on-controller-press first-child
                               controller
                               (controller-button-event-button event))))
       ((controller-button-up-event? event)
        (let ((controller
               (lookup-controller kernel
                                  (controller-button-event-which event))))
          (on-controller-release first-child
                                 controller
                                 (controller-button-event-button event))))
       ((controller-axis-event? event)
        (let ((controller
               (lookup-controller kernel
                                  (controller-axis-event-which event))))
          (on-controller-move first-child
                              controller
                              (controller-axis-event-axis event)
                              (/ (controller-axis-event-value event) 32768.0)))))))
  ;; Process all pending events.
  (let loop ((event (poll-event)))
    (when event
      (process-event event)
      (loop (poll-event))))
  ;; Proceed with standard update procedure.
  (next-method))

(define (boot-kernel kernel first-node)
  (sdl-init)
  ;; This will throw an error if any audio subsystem is unavailable,
  ;; but not every audio subsystem is needed so don't crash the
  ;; program over it.
  (false-if-exception (mixer-init))
  (open-audio)
  (start-text-input)
  ;; Discover all game controllers that are already connected.  New
  ;; connections/disconnections will be handled by events as they occur.
  (initialize-controllers kernel)
  (let ((wc (window-config kernel)))
    (set! (window kernel)
          (make-window #:opengl? #t
                       #:title (title wc)
                       #:size (list (width wc) (height wc))
                       #:fullscreen? (fullscreen? wc)))
    (set! (gl-context kernel) (make-gl-context (window kernel)))
    (dynamic-wind
      (const #t)
      (lambda ()
        (parameterize ((current-kernel kernel))
          (attach-to kernel first-node)
          (activate kernel)
          ;; TODO: Add error handler
          (run-game #:update (lambda (dt) (update* kernel dt))
                    #:render (lambda (alpha) (render* kernel alpha))
                    #:time sdl-ticks
                    #:update-hz (update-hz kernel))))
      (lambda ()
        (deactivate kernel)
        (close-window! (window kernel))))))