dnl -*- Autoconf -*-

AC_INIT(Sly, 0.2.0)
AC_CONFIG_SRCDIR(sly)
AC_CONFIG_AUX_DIR([build-aux])
AM_INIT_AUTOMAKE([color-tests -Wall -Wno-portability foreign])
AM_SILENT_RULES([yes])

AC_PATH_PROG([GUILE], [guile])
AC_CONFIG_FILES([Makefile doc/Makefile examples/Makefile data/Makefile])
AC_CONFIG_FILES([sly/config.scm])
AC_CONFIG_FILES([sandbox], [chmod +x sandbox])
AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])

# Prepare a version of $datadir that does not contain references to
# shell variables.
sly_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
sly_datadir="`eval eval echo $datadir | sed -e "s|NONE|$sly_prefix|g"`"
AC_SUBST([sly_datadir])

GUILE_PROGS([2.0.11])
GUILE_MODULE_REQUIRED([sdl2])
GUILE_MODULE_REQUIRED([sdl2 image])
GUILE_MODULE_REQUIRED([sdl2 mixer])
GUILE_MODULE_REQUIRED([sdl2 ttf])
GUILE_MODULE_REQUIRED([gl])

LIBGSLCBLAS="libgslcblas"
LIBGSLCBLAS_LIBDIR="no"
LIBGSLCBLAS_PREFIX="no"

AC_ARG_WITH([libgslcblas-prefix],
  [AS_HELP_STRING([--with-libgslcblas-prefix=DIR], [search for GSL CBLAS in DIR])],
  [case "$withval" in
    yes|no)
      ;;
    *)
      LIBGSLCBLAS="$withval/lib/libgslcblas"
      LIBGSLCBLAS_PREFIX="$withval"
      LIBGSLCBLAS_LIBDIR="$withval/lib"
      ;;
   esac])

dnl Library name suitable for `dynamic-link'.
AC_MSG_CHECKING([for libgslcblas shared library name])
AC_MSG_RESULT([$LIBGSLCBLAS])
AC_SUBST([LIBGSLCBLAS])
AC_SUBST([LIBGSLCBLAS_PREFIX])
AC_SUBST([LIBGSLCBLAS_LIBDIR])

PKG_CHECK_MODULES([GSL], [gsl])

AC_OUTPUT