summaryrefslogtreecommitdiff
path: root/shroud/ui/show.scm
blob: 6e0c61ff5aee3a4a60ba90dbd831e8cb6838f013 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
;;; Shroud
;;; Copyright © 2015 David Thompson <davet@gnu.org>
;;;
;;; Shroud is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or
;;; (at your option) any later version.
;;;
;;; Shroud is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with Shroud.  If not, see <http://www.gnu.org/licenses/>.

(define-module (shroud ui show)
  #:use-module (ice-9 format)
  #:use-module (ice-9 match)
  #:use-module (srfi srfi-1)
  #:use-module (srfi srfi-37)
  #:use-module (shroud utils)
  #:use-module (shroud secret)
  #:use-module (shroud ui)
  #:export (shroud-show))

(define (show-help)
  (format #t "Usage: shroud show [OPTION] ID [KEY ...]
Show secret named ID.~%")
  (display "
  -c, --clipboard        copy output to the X clipboard")
  (display "
  -h, --help             display this help and exit")
  (display "
  --version              display version information and exit")
  (newline))

(define %options
  (list (option '(#\h "help") #f #f
                (lambda args
                  (show-help)
                  (exit 0)))
        (option '("version") #f #f
                (lambda args
                  (show-version-and-exit)))
        (option '("clipboard" #\c) #f #f
                (lambda (opt name arg result)
                  (alist-cons 'clipboard? #t result)))))

(define %default-options '())

(define (process-args args)
  (args-fold args %options
             (lambda (opt name arg result)
               (leave "~A: unrecognized option" name))
             (lambda (arg result)
               (if (assq-ref result 'id)
                   (alist-cons 'key arg result)
                   (alist-cons 'id arg result)))
             %default-options))

(define* (display-secret secret keys #:optional (port (current-output-port)))
  (match keys
    (()
     (for-each (match-lambda
                ((key . value)
                 (format port "~a\t~a~%" key value)))
               (secret-contents secret)))
    ((keys ...)
     (for-each (match-lambda
                ((key . value)
                 (when (member key keys)
                   (format port "~a~%" value))))
               (secret-contents secret)))))

(define (shroud-show config db . args)
  (let* ((opts       (process-args args))
         (id         (leave-if-false (assq-ref opts 'id)
                                     "no secret ID given"))
         (keys       (alist-pick opts 'key))
         (clipboard? (assq-ref opts 'clipboard?))
         (secret     (vhash-ref (secrets-by-id (force db)) id)))

    (unless secret
      (leave "secret '~a' does not exist" id))

    (if clipboard?
        (call-with-clipboard
         (lambda (port)
           (display-secret secret keys port)
           (display "copied secret to clipboard\n"
                    (current-error-port))))
        (display-secret secret keys))

    ;; Database remains unaltered.
    #f))