;;; Lisparuga
;;; Copyright © 2020 David Thompson <dthompson2@worcester.edu>
;;;
;;; Lisparuga is free software: you can redistribute it and/or modify
;;; it under the terms of the GNU General Public License as published
;;; by the Free Software Foundation, either version 3 of the License,
;;; or (at your option) any later version.
;;;
;;; Lisparuga is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with Lisparuga.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:
;;
;; Game container.  Handles all the state, logic, and rendering for
;; the game itself.
;;
;;; Code:

(define-module (lisparuga game)
  #:use-module (chickadee math rect)
  #:use-module (chickadee math vector)
  #:use-module (chickadee render color)
  #:use-module (chickadee render texture)
  #:use-module (chickadee scripting)
  #:use-module (ice-9 format)
  #:use-module (lisparuga actor)
  #:use-module (lisparuga asset)
  #:use-module (lisparuga bullets)
  #:use-module (lisparuga config)
  #:use-module (lisparuga enemy)
  #:use-module (lisparuga node)
  #:use-module (lisparuga node-2d)
  #:use-module (lisparuga player)
  #:use-module (oop goops)
  #:export (<game>
            steer-player
            start-player-shooting
            stop-player-shooting
            toggle-player-polarity
            fire-player-homing-missiles))

(define-asset clouds (load-image (scope-asset "images/clouds.png")))
(define-asset player-bullet-atlas
  (load-tile-atlas (scope-asset "images/player-bullets.png") 16 16))
(define-asset enemy-bullet-atlas
  (load-tile-atlas (scope-asset "images/enemy-bullets.png") 24 24))

;; nodes needed:
;; scrolling background
(define-class <game> (<node-2d>))

(define-method (on-boot (game <game>))
  (let* ((player-bullets (make <bullet-field>
                           #:name 'player-bullets
                           #:rank 2
                           #:capacity 500
                           #:texture-atlas player-bullet-atlas))
         (player (make-player player-bullets))
         (enemy-bullets (make <bullet-field>
                          #:name 'enemy-bullets
                          #:rank 4
                          #:capacity 1000
                          #:texture-atlas enemy-bullet-atlas))
         (ui (make <node-2d>
               #:name 'ui
               #:rank 999)))
    (set! (rank player) 1)
    (attach-to game
               (make <sprite>
                 #:name 'clouds
                 #:rank 0
                 #:texture clouds)
               player
               player-bullets
               (make <node-2d>
                 #:name 'enemies
                 #:rank 3)
               enemy-bullets
               ui)
    ;; Setup UI elements
    (attach-to ui
               (make <label>
                 #:name 'score
                 #:position (vec2 2.0 226.0))
               (make <label>
                 #:name 'chain
                 #:position (vec2 2.0 210.0))
               (make <label>
                 #:name 'energy
                 #:position (vec2 2.0 18.0))
               (make <label>
                 #:name 'lives
                 #:position (vec2 2.0 2.0)))
    (update-ui game)
    ;; Test enemy
    (spawn-enemy game (make-utatsugumi 'white 10.0 180.0))
    (spawn-enemy game (make-utatsugumi 'white 30.0 180.0))
    (spawn-enemy game (make-utatsugumi 'white 50.0 180.0))
    (spawn-enemy game (make-utatsugumi 'black 70.0 180.0))
    (spawn-enemy game (make-utatsugumi 'black 90.0 180.0))
    (spawn-enemy game (make-utatsugumi 'black 110.0 180.0))
    (spawn-enemy game (make-utatsugumi 'white 130.0 180.0))
    (spawn-enemy game (make-utatsugumi 'white 150.0 180.0))))

(define (update-ui game)
  (set! (text (& game ui score))
    (format #f "~9,'0d" (score (& game player))))
  (set! (text (& game ui chain))
    (format #f "CHAIN ~a: ~a"
            (let ((n (chain (& game player))))
              (if (< n 9) (number->string n) "MAX"))
            (list->string
             (map (lambda (polarity)
                    (if (eq? polarity 'white)
                        #\W
                        #\B))
                  (chain-progress (& game player))))))
  (set! (text (& game ui energy))
    (format #f "E~d" (quotient (energy (& game player)) 10)))
  (set! (text (& game ui lives))
    (format #f "x~d" (max (- (lives (& game player)) 1) 0))))

(define-method (update (game <game>) dt)
  (let ((refresh-ui? #f)
        (player (& game player)))
    ;; enemy -> player bullet collision
    ;; enemy -> player collision
    (for-each (lambda (enemy)
                (cond
                 ((and (collide (& game player-bullets) enemy)
                       (dead? enemy))
                  (on-kill player enemy)
                  (fire-parting-shots-maybe enemy player)
                  (detach enemy)
                  (set! refresh-ui? #t))
                 ((collide player enemy)
                  (set! refresh-ui? #t))))
              (children (& game enemies)))
    ;; player -> enemy bullet collision
    (when (collide (& game enemy-bullets) (& game player))
      (set! refresh-ui? #t))
    (when refresh-ui?
      (update-ui game))))

(define-method (spawn-enemy (game <game>) enemy)
  (set! (bullet-field enemy) (& game enemy-bullets))
  (attach-to (& game enemies) enemy))

(define-method (steer-player (game <game>) up? down? left? right?)
  (steer (& game player) up? down? left? right?))

(define-method (start-player-shooting (game <game>))
  (start-shooting (& game player)))

(define-method (stop-player-shooting (game <game>))
  (stop-shooting (& game player)))

(define-method (toggle-player-polarity (game <game>))
  (toggle-polarity (& game player)))

(define-method (fire-player-homing-missiles (game <game>))
  (fire-homing-missiles (& game player) (children (& game enemies)))
  (update-ui game))