summaryrefslogtreecommitdiff
path: root/sdl2/input
diff options
context:
space:
mode:
Diffstat (limited to 'sdl2/input')
-rw-r--r--sdl2/input/game-controller.scm155
-rw-r--r--sdl2/input/joystick.scm114
2 files changed, 269 insertions, 0 deletions
diff --git a/sdl2/input/game-controller.scm b/sdl2/input/game-controller.scm
new file mode 100644
index 0000000..66441a9
--- /dev/null
+++ b/sdl2/input/game-controller.scm
@@ -0,0 +1,155 @@
+;;; guile-sdl2 --- FFI bindings for SDL2
+;;; Copyright © 2016 David Thompson <davet@gnu.org>
+;;;
+;;; This file is part of guile-sdl2.
+;;;
+;;; Guile-sdl2 is free software; you can redistribute it and/or modify
+;;; it under the terms of the GNU Lesser General Public License as
+;;; published by the Free Software Foundation; either version 3 of the
+;;; License, or (at your option) any later version.
+;;;
+;;; Guile-sdl2 is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+;;; General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU Lesser General Public
+;;; License along with guile-sdl2. If not, see
+;;; <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+;;
+;; Joystick input.
+;;
+;;; Code:
+
+(define-module (sdl2 input game-controller)
+ #:use-module (ice-9 match)
+ #:use-module (srfi srfi-9)
+ #:use-module (srfi srfi-9 gnu)
+ #:use-module (system foreign)
+ #:use-module ((sdl2 bindings) #:prefix ffi:)
+ #:use-module (sdl2)
+ #:export (open-game-controller
+ close-game-controller
+ game-controller?
+ game-controller-attached?
+ game-controller-joystick
+ game-controller-name
+ game-controller-axis
+ game-controller-button-pressed?
+ game-controller-index?))
+
+(define-wrapped-pointer-type <game-controller>
+ game-controller?
+ wrap-game-controller unwrap-game-controller
+ (lambda (game-controller port)
+ (format port "#<game-controller ~a>"
+ (game-controller-name game-controller))))
+
+(define-record-type <game-controller>
+ (make-game-controller pointer joystick)
+ game-controller?
+ (pointer unwrap-game-controller)
+ (joystick %game-controller-joystick))
+
+(set-record-type-printer! <game-controller>
+ (lambda (game-controller port)
+ (format port "#<game-controller ~s>"
+ (game-controller-name game-controller))))
+
+(define wrap-joystick (@@ (sdl2 input joystick) wrap-joystick))
+
+(define (open-game-controller joystick-index)
+ "Return a game controller object for the physical joystick device
+associated with ."
+ (let ((ptr (ffi:sdl-game-controller-open joystick-index)))
+ (if (null-pointer? ptr)
+ (sdl-error "open-game-controller" "failed to open game controller")
+ (let ((joystick (wrap-joystick
+ (ffi:sdl-game-controller-get-joystick ptr))))
+ (make-game-controller ptr joystick)))))
+
+(define (close-game-controller controller)
+ "Close CONTROLLER."
+ (ffi:sdl-game-controller-close (unwrap-game-controller controller)))
+
+(define (game-controller-joystick controller)
+ "Return the underlying joystick object associated with CONTROLLER."
+ (%game-controller-joystick controller))
+
+(define (game-controller-attached? controller)
+ "Return #t if CONTROLLER is currently in use."
+ (= (ffi:sdl-game-controller-get-attached (unwrap-game-controller controller)) 1))
+
+(define (game-controller-name controller)
+ "Return the human readable name for CONTROLLER."
+ (pointer->string (ffi:sdl-game-controller-name (unwrap-game-controller controller))))
+
+(define (axis-symbol->int axis)
+ (match axis
+ ('left-x ffi:SDL_CONTROLLER_AXIS_LEFTX)
+ ('left-y ffi:SDL_CONTROLLER_AXIS_LEFTY)
+ ('right-x ffi:SDL_CONTROLLER_AXIS_RIGHTX)
+ ('right-x ffi:SDL_CONTROLLER_AXIS_RIGHTY)
+ ('trigger-left ffi:SDL_CONTROLLER_AXIS_TRIGGERLEFT)
+ ('trigger-right ffi:SDL_CONTROLLER_AXIS_TRIGGERRIGHT)))
+
+(define (game-controller-axis controller axis)
+ "Return a number in the range [-32768, 32767] representing the
+current state of AXIS on CONTROLLER.
+
+AXIS may be one of the following symbols:
+- left-x
+- left-y
+- right-x
+- right-y
+- trigger-left
+- trigger-right"
+ (ffi:sdl-game-controller-get-axis (unwrap-game-controller controller)
+ (axis-symbol->int axis)))
+
+(define (button-symbol->int button)
+ (match button
+ ('a ffi:SDL_CONTROLLER_BUTTON_A)
+ ('b ffi:SDL_CONTROLLER_BUTTON_B)
+ ('x ffi:SDL_CONTROLLER_BUTTON_X)
+ ('y ffi:SDL_CONTROLLER_BUTTON_Y)
+ ('back ffi:SDL_CONTROLLER_BUTTON_BACK)
+ ('guide ffi:SDL_CONTROLLER_BUTTON_GUIDE)
+ ('start ffi:SDL_CONTROLLER_BUTTON_START)
+ ('left-stick ffi:SDL_CONTROLLER_BUTTON_LEFTSTICK)
+ ('right-stick ffi:SDL_CONTROLLER_BUTTON_RIGHTSTICK)
+ ('left-shoulder ffi:SDL_CONTROLLER_BUTTON_LEFTSHOULDER)
+ ('right-shoulder ffi:SDL_CONTROLLER_BUTTON_RIGHTSHOULDER)
+ ('dpad-up ffi:SDL_CONTROLLER_BUTTON_DPAD_UP)
+ ('dpad-down ffi:SDL_CONTROLLER_BUTTON_DPAD_DOWN)
+ ('dpad-left ffi:SDL_CONTROLLER_BUTTON_DPAD_LEFT)
+ ('dpad-right ffi:SDL_CONTROLLER_BUTTON_DPAD_RIGHT)))
+
+(define (game-controller-button-pressed? controller button)
+ "Return #t if BUTTON is pressed on CONTROLLER.
+
+BUTTON may be one of the following symbols:
+- a
+- b
+- x
+- y
+- back
+- guide
+- start
+- left-stick
+- right-stick
+- left-shoulder
+- right-shoulder
+- dpad-up
+- dpad-down
+- dpad-left
+- dpad-right"
+ (= (ffi:sdl-game-controller-get-button (unwrap-game-controller controller)
+ (button-symbol->int button))
+ 1))
+
+(define (game-controller-index? joystick-index)
+ "Return #t if JOYSTICK-INDEX is a valid game controller index."
+ (= (ffi:sdl-is-game-controller joystick-index) 1))
diff --git a/sdl2/input/joystick.scm b/sdl2/input/joystick.scm
new file mode 100644
index 0000000..ecab8ec
--- /dev/null
+++ b/sdl2/input/joystick.scm
@@ -0,0 +1,114 @@
+;;; guile-sdl2 --- FFI bindings for SDL2
+;;; Copyright © 2016 David Thompson <davet@gnu.org>
+;;;
+;;; This file is part of guile-sdl2.
+;;;
+;;; Guile-sdl2 is free software; you can redistribute it and/or modify
+;;; it under the terms of the GNU Lesser General Public License as
+;;; published by the Free Software Foundation; either version 3 of the
+;;; License, or (at your option) any later version.
+;;;
+;;; Guile-sdl2 is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+;;; General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU Lesser General Public
+;;; License along with guile-sdl2. If not, see
+;;; <http://www.gnu.org/licenses/>.
+
+;;; Commentary:
+;;
+;; Joystick input.
+;;
+;;; Code:
+
+(define-module (sdl2 input joystick)
+ #:use-module (ice-9 format)
+ #:use-module (ice-9 match)
+ #:use-module (system foreign)
+ #:use-module ((sdl2 bindings) #:prefix ffi:)
+ #:use-module (sdl2)
+ #:export (num-joysticks
+ open-joystick
+ close-joystick
+ joystick?
+ joystick-instance-id
+ joystick-power-level
+ joystick-num-axes
+ joystick-num-balls
+ joystick-num-buttons
+ joystick-num-hats))
+
+(define (num-joysticks)
+ "Return the current number of connected joystick devices."
+ (ffi:sdl-num-joysticks))
+
+(define-wrapped-pointer-type <joystick>
+ joystick?
+ wrap-joystick unwrap-joystick
+ (lambda (joystick port)
+ (format port "#<joystick id: ~d>"
+ (joystick-instance-id joystick))))
+
+(define (open-joystick device-index)
+ "Return a joystick object for the physical joystick device
+associated with DEVICE-INDEX."
+ (let ((ptr (ffi:sdl-joystick-open device-index)))
+ (if (null-pointer? ptr)
+ (sdl-error "open-joystick" "failed to open joystick")
+ (wrap-joystick ptr))))
+
+(define (close-joystick joystick)
+ "Close JOYSTICK."
+ (ffi:sdl-joystick-close (unwrap-joystick joystick)))
+
+(define (joystick-instance-id joystick)
+ "Return the instance id of JOYSTICK."
+ (ffi:sdl-joystick-instance-id (unwrap-joystick joystick)))
+
+(define (joystick-attached? joystick)
+ "Return #t if JOYSTICK has been opened."
+ (= (ffi:sdl-joystick-get-attached (unwrap-joystick joystick)) 1))
+
+(define (joystick-power-level joystick)
+ "Return the symbolic battery power level for JOYSTICK, either
+'unknown', 'empty', 'low', 'medium', 'full', or 'wired'."
+ (let ((level (ffi:sdl-joystick-current-power-level
+ (unwrap-joystick joystick))))
+ (cond
+ ((= level ffi:SDL_JOYSTICK_POWER_UNKNOWN) 'unknown)
+ ((= level ffi:SDL_JOYSTICK_POWER_EMPTY) 'empty)
+ ((= level ffi:SDL_JOYSTICK_POWER_LOW) 'low)
+ ((= level ffi:SDL_JOYSTICK_POWER_MEDIUM) 'medium)
+ ((= level ffi:SDL_JOYSTICK_POWER_FULL) 'full)
+ ((= level ffi:SDL_JOYSTICK_POWER_WIRED) 'wired))))
+
+(define (joystick-num-axes joystick)
+ "Return the number of axes for JOYSTICK."
+ (ffi:sdl-joystick-num-axes (unwrap-joystick joystick)))
+
+(define (joystick-num-balls joystick)
+ "Return the number of balls for JOYSTICK."
+ (ffi:sdl-joystick-num-balls (unwrap-joystick joystick)))
+
+(define (joystick-num-buttons joystick)
+ "Return the number of buttons for JOYSTICK."
+ (ffi:sdl-joystick-num-buttons (unwrap-joystick joystick)))
+
+(define (joystick-num-hats joystick)
+ "Return the number of hats for JOYSTICK."
+ (ffi:sdl-joystick-num-hats (unwrap-joystick joystick)))
+
+(define (joystick-axis joystick axis-index)
+ "Return a number in the range [-32768, 32767] representing the
+current state of AXIS-INDEX on JOYSTICK. On most joysticks, use 0 to
+query the X axis and 1 to query the Y axis."
+ (ffi:sdl-joystick-get-axis (unwrap-joystick joystick) axis-index))
+
+(define (joystick-button-pressed? joystick button-index)
+ "Return #t if BUTTON-INDEX is pressed on JOYSTICK. Button indices
+start from 0."
+ (= (ffi:sdl-joystick-get-button (unwrap-joystick joystick) button-index) 1))
+
+;; TODO: joystick-hat and joystick-ball
generated by cgit v1.2.3 (git 2.25.4) at 2024-07-01 19:32:30 +0000