summaryrefslogtreecommitdiff
path: root/dotfiles/.dmd.d/init.scm
blob: 99edf739ab1c9aa70b4f78628e34aa8117690596 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
(use-modules (ice-9 match))

(define-syntax-rule (forever body ...)
  (while #t body ...))

(define-syntax-rule (with-fork body ...)
  (match (primitive-fork)
    (0 (begin body ...))
    (pid pid)))

(define (simple-service program)
  (make <service>
    #:provides (list (string->symbol program))
    #:requires '()
    #:start (make-forkexec-constructor (list program))
    #:stop (make-kill-destructor)))

(define %home (getenv "HOME"))

(register-services
 ;; Emacs
 (make <service>
   #:provides '(emacs)
   #:requires '()
   ;; FIXME: Stopping this service doesn't kill emacs because it was
   ;; daemonized.
   #:start (make-forkexec-constructor (list "emacs" "--daemon")))
 ;; Customize X key bindings.
 (make <service>
   #:provides '(xmodmap)
   #:requires '()
   #:start (make-forkexec-constructor
            (list "xmodmap" (string-append %home "/.xmodmap"))))
 ;; GPG/SSH agent.
 (make <service>
   #:provides '(gpg-agent)
   #:requires '()
   #:start (make-forkexec-constructor
            (list "gpg-agent"
                  "--enable-ssh-support"
                  "--pinentry-program"
                  (string-append %home "/.guix-profile/bin/pinentry-gtk-2"))))
 ;; Mailbox sync.
 (make <service>
   #:provides '(offlineimap)
   #:requires '()
   #:start (lambda args
             (with-fork
              ;; OfflineIMAP's "autorefresh" mode consistently
              ;; consumes all of the RAM on my machine, so let's just
              ;; run it in a loop instead.
              (forever
               (system* "offlineimap")
               (sleep 20))))
   #:stop (make-kill-destructor))
 ;; Music.
 (simple-service "mpd")
 (simple-service "mpdscribble"))

;; Send dmd into the background
(action 'dmd 'daemonize)

;; Services to start when dmd starts:
(for-each start '(emacs xmodmap gpg-agent offlineimap))