blob: dc74a5fb1e7c3ecbcf10d2881fde65ecc6b6df49 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
|
;;; Chickadee Game Toolkit
;;; Copyright © 2023 David Thompson <dthompson2@worcester.edu>
;;;
;;; Licensed under the Apache License, Version 2.0 (the "License");
;;; you may not use this file except in compliance with the License.
;;; You may obtain a copy of the License at
;;;
;;; http://www.apache.org/licenses/LICENSE-2.0
;;;
;;; Unless required by applicable law or agreed to in writing, software
;;; distributed under the License is distributed on an "AS IS" BASIS,
;;; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
;;; See the License for the specific language governing permissions and
;;; limitations under the License.
(define-module (chickadee graphics seagull primitives)
#:use-module (chickadee graphics seagull base)
#:use-module (chickadee graphics seagull syntax)
#:use-module (chickadee graphics seagull types)
#:use-module (chickadee graphics seagull utils)
#:use-module (ice-9 match)
#:use-module (srfi srfi-1)
#:use-module (srfi srfi-9)
#:export (make-primitive-operator
define-primitive-operator
lookup-primitive-operator
primitive-operator?
primitive-operator-name
primitive-operator-glsl-name
primitive-operator-stages
primitive-operator-arity
primitive-operator-expand
primitive-operator-infix?
primitive-operator-type))
(define-record-type <primitive-operator>
(%make-primitive-operator name glsl-name stages arity expand infix? type)
primitive-operator?
(name primitive-operator-name)
(glsl-name primitive-operator-glsl-name)
(stages primitive-operator-stages)
(arity primitive-operator-arity)
(expand primitive-operator-expand)
(infix? primitive-operator-infix?)
(type primitive-operator-type))
(define (make-default-expander name)
(lambda (args src expand)
(make-primitive-call src name (map expand args))))
(define* (make-primitive-operator #:key name type proc arity
(glsl-name name)
(stages (list stage:vertex stage:fragment))
(expand (make-default-expander name))
infix?)
(%make-primitive-operator name glsl-name stages arity expand infix? type))
(define *primitive-operators* (make-hash-table))
(define (register-primitive-operator! primitive-operator)
(hashq-set! *primitive-operators*
(primitive-operator-name primitive-operator)
primitive-operator)
*unspecified*)
(define (lookup-primitive-operator name)
(hashq-ref *primitive-operators* name))
(define-syntax-rule (define-primitive-operator name args ...)
(register-primitive-operator!
(make-primitive-operator #:name 'name args ...)))
(define int (lookup-type 'int))
(define -> make-function-type)
(define-primitive-operator +
#:arity 2
#:type (-> (list int int) (list int))
#:infix? #t
#:expand
(lambda (args src expand)
(let loop ((args args))
(match args
(()
(make-constant src 0))
((n)
(expand n))
((n . rest)
(make-primitive-call src '+ (list (expand n) (loop rest))))))))
(define-primitive-operator -
#:arity 2
#:type (-> (list int int) (list int))
#:infix? #t
#:expand
(lambda (args src expand)
(let loop ((args args))
(match args
((n) (make-primitive-call src '- (list (expand n) (make-constant src 0))))
((m n)
(make-primitive-call src '- (list (expand m) (expand n))))
((n . rest)
(make-primitive-call src '- (list (expand n) (loop rest))))))))
(define-primitive-operator *
#:arity 2
#:type (-> (list int int) (list int))
#:infix? #t
#:expand
(lambda (args src expand)
(let loop ((args args))
(match args
(() (make-constant src 1))
((n) (expand n))
((n . rest)
(make-primitive-call src '* (list (expand n) (loop rest))))))))
(define-primitive-operator /
#:arity 2
#:type (-> (list int int) (list int))
#:infix? #t
#:expand
(lambda (args src expand)
(match args
((n)
(make-primitive-call src '/ (list (make-constant src 1) (expand n))))
((m n)
(make-primitive-call src '/ (list (expand m) (expand n))))
((m n . rest)
(let loop ((rest rest)
(exp (make-primitive-call src '/ (list (expand m) (expand n)))))
(match rest
((l)
(make-primitive-call src '/ (list exp (expand l))))
((l . rest)
(loop rest (make-primitive-call src '/ (list exp (expand l)))))))))))
(define-primitive-operator = #:arity 2 #:infix? #t)
(define-primitive-operator vec2 #:arity 2)
(define-primitive-operator vec3 #:arity 3)
(define-primitive-operator vec4 #:arity 4)
|
