dnl -*- Autoconf -*-

AC_INIT(chickadee, 0.7.0)
AC_CONFIG_SRCDIR(chickadee)
AC_CONFIG_AUX_DIR([build-aux])
AM_INIT_AUTOMAKE([color-tests -Wall -Wno-portability foreign])
AM_SILENT_RULES([yes])

AC_PATH_PROG([GUILE], [guile])
AC_CONFIG_FILES([Makefile])
AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])
AC_CONFIG_FILES([chickadee/config.scm])

# Prepare a version of $datadir that does not contain references to
# shell variables.
chickadee_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
chickadee_datadir="`eval eval echo $datadir | sed -e "s|NONE|$chickadee_prefix|g"`"
AC_SUBST([chickadee_datadir])

GUILE_PKG([3.0 2.2])
GUILE_PROGS

GUILE_MODULE_REQUIRED([gl])
GUILE_MODULE_REQUIRED([sdl2])

PKG_CHECK_MODULES([OpenAL], [openal])
PKG_CHECK_VAR([OPENAL_LIBDIR], [openal], [libdir])
AC_MSG_CHECKING([OpenAL library path])
AS_IF([test "x$OPENAL_LIBDIR" = "x"], [
  AC_MSG_FAILURE([Unable to identify OpenAL lib path.])
], [
  AC_MSG_RESULT([$OPENAL_LIBDIR])
])
AC_SUBST([OPENAL_LIBDIR])

PKG_CHECK_MODULES([Vorbis], [vorbis])
PKG_CHECK_VAR([VORBIS_LIBDIR], [vorbis], [libdir])
AC_MSG_CHECKING([Vorbis library path])
AS_IF([test "VORBIS_LIBDIR" = "x"], [
  AC_MSG_FAILURE([Unable to identify Vorbis lib path.])
], [
  AC_MSG_RESULT([$VORBIS_LIBDIR])
])
AC_SUBST([VORBIS_LIBDIR])

PKG_CHECK_MODULES([mpg123], [libmpg123])
PKG_CHECK_VAR([MPG123_LIBDIR], [libmpg123], [libdir])
AC_MSG_CHECKING([mpg123 library path])
AS_IF([test "MPG123_LIBDIR" = "x"], [
  AC_MSG_FAILURE([Unable to identify mpg123 lib path.])
], [
  AC_MSG_RESULT([$MPG123_LIBDIR])
])
AC_SUBST([MPG123_LIBDIR])

PKG_CHECK_MODULES([freetype], [freetype2])
PKG_CHECK_VAR([FREETYPE_LIBDIR], [freetype2], [libdir])
AC_MSG_CHECKING([freetype library path])
AS_IF([test "FREETYPE_LIBDIR" = "x"], [
  AC_MSG_FAILURE([Unable to identify freetype lib path.])
], [
  AC_MSG_RESULT([$FREETYPE_LIBDIR])
])
AC_SUBST([FREETYPE_LIBDIR])

AC_OUTPUT