(use-modules (gnu packages autotools)
             (gnu packages base)
             (gnu packages guile)
             (gnu packages guile-xyz)
             (gnu packages rsync)
             (guix git-download)
             (guix packages)
             (guix profiles)
             (guix utils))

(define haunt*
  (let ((commit "63afd408c890aec7d62c754ae1399c901ff2a794"))
    (package
     (inherit haunt)
     (source (origin
              (method git-fetch)
              (uri (git-reference
                    (url "https://git.dthompson.us/haunt.git")
                    (commit commit)))
              (sha256
               (base32
                "0mf8b9w7ky8grsy4cq9573ggg4gm465fgvk8dnk7kxma810fvxmx"))))
     (native-inputs
      `(("autoconf" ,autoconf)
        ("automake" ,automake)
        ,@(package-native-inputs haunt)))
     (inputs
      (cons `("rsync" ,rsync)
            (package-inputs haunt)))
     (arguments
      (substitute-keyword-arguments (package-arguments haunt)
        ((#:phases phases)
         `(modify-phases ,phases
            (add-after 'unpack 'bootstrap
              (lambda _
                (invoke "sh" "bootstrap"))))))))))

(packages->manifest
 (list guile-3.0
       guile-syntax-highlight
       haunt*))