(define-module (bonnie-bee splash)
  #:use-module (bonnie-bee assets)
  #:use-module (bonnie-bee common)
  #:use-module (bonnie-bee game)
  #:use-module (chickadee graphics color)
  #:use-module (chickadee math vector)
  #:use-module (chickadee scripting)
  #:use-module (oop goops)
  #:use-module (catbird)
  #:use-module (catbird camera)
  #:use-module (catbird kernel)
  #:use-module (catbird mode)
  #:use-module (catbird node)
  #:use-module (catbird node-2d)
  #:use-module (catbird region)
  #:use-module (catbird scene)
  #:export (launch-game))

(define-class <splash-mode> (<major-mode>))

(define %text-color (rgb #x181425))

(define-method (on-enter (mode <splash-mode>))
  (let ((scene (parent mode)))
    (attach-to scene
               (make <sprite>
                 #:texture lightness-image)
               (make <sprite>
                 #:texture chickadee-image
                 #:position (vec2 (/ %game-width 2.0)
                                  (/ %game-height 2.0))
                 #:origin (vec2 8.0 8.0)
                 #:scale (vec2 4.0 4.0))
               (make <label>
                 #:rank 1
                 #:position (vec2 (/ %game-width 2.0) 70.5)
                 #:font monogram-font
                 #:color %text-color
                 #:align 'center
                 #:vertical-align 'center
                 #:text "Made with Chickadee")
               (make <label>
                 #:rank 1
                 #:position (vec2 (/ %game-width 2.0) 50.5)
                 #:font monogram-font
                 #:color %text-color
                 #:align 'center
                 #:vertical-align 'center
                 #:text "https://dthompson.us/projects/chickadee.html"))
    (run-script scene
      (unless (getenv "SKIP_SPLASH")
        (fade-in scene 1.0)
        (sleep 1.0)
        (fade-out scene 1.0))
      (let ((new-scene (make <scene>))
            (region (car (all-regions))))
        (replace-scene region (make-game-scene))))))

(define (launch-game)
  (set! *random-state* (random-state-from-platform))
  (run-catbird
   (lambda ()
     (let ((region (create-full-region))
           (scene (make <scene>)))
       (take-controller-focus 0 region)
       (replace-scene region scene)
       (replace-major-mode scene (make <splash-mode>))
       (set! (camera region)
             (make <camera-2d>
               #:width %game-width
               #:height %game-height))))
   #:width %window-width
   #:height %window-height
   #:title "Bonnie Bee and the Pesticidal Tendencies"))